mcpe/platforms/sdl/android/app/build.gradle

apply plugin: 'com.android.application'

android {
    compileSdk 34
    defaultConfig {
        applicationId 'io.github.reminecraftpe'
        minSdkVersion 21
        //noinspection EditedTargetSdkVersion
        targetSdkVersion 34
        versionCode 1
        versionName '1.0'
        externalNativeBuild {
            cmake {
                arguments '-DANDROID_PLATFORM=android-21', '-DANDROID_STL=c++_static'
                abiFilters 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
            }
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    applicationVariants.configureEach { variant ->
        //noinspection ConfigurationAvoidance
        tasks["merge${variant.name.capitalize()}Assets"]
            .dependsOn("externalNativeBuild${variant.name.capitalize()}")
    }
    sourceSets.main {
        java.srcDir '../../../../thirdparty/SDL2/src/android-project/app/src/main/java'
        assets.srcDir '../../../../game'
    }
    externalNativeBuild {
        cmake {
            path '../../CMakeLists.txt'
            version '3.22.1'
        }
    }
    lint {
        abortOnError false
    }
    namespace 'io.github.reminecraftpe'
}